<データ組込み時に，日別ファイルは日付順に並ぶようにする>
データ組込みフォームでデータを組込む時に，連続組込みするには，ファイルがきれいに並んでいなければならいないのですが，当初，連続組込みは，CD-ROMからの組込みを想定していました。
そのためファイルは種類順に並んでいましたが，2000年以降は，日別ファイルとして取得している人がほとんどです。 この時に，連続組込みをしようとすると，毎週取得した騎手ファイルや調教師ファイルの情報を反映させるために，日付順にきれいに入れる必要があります。
Utilities標準モジュールの以下の pfConvertSameNameプロシージャを変更してください。 (00.08.20 Dim strJosu As Sring → String に修正しました。00.08.26 赤色のところ)
--------------------------------------------------------------------------------------------------------
Private Function pfConvertSameName(item As Variant) As Variant
On Error GoTo Err_pfConvertSameName
'開催場数の違いを吸収するために，同名に変換しています。
'開催場数の違いによるファイル名の違いは，第３次JRA-VANデータ仕様 の 登録データ一覧(Jvds302g)を参照してください。
'同じ，日付のファイルの場合，抹消ファイル，調教師，騎手，競走馬，出馬表，成績 の順に並ぶようにします。
'CD-ROMからのような開催別のファイルの場合は，日別ファイルと混ざらないように後ろに持っていきます。
Dim strFileType As String
Dim strJosu As String
strFileType = Left$(item, 1)
strJosu = Mid$(item, 2, 1)
Select Case strFileType
Case "c" '調教師 現役・引退
pfConvertSameName = Mid(item, 3, 6) & "b"
Case "k" '騎手 現役・引退
pfConvertSameName = Mid(item, 3, 6) & "c"
Case "u" '競走馬
If strJosu = "1" Or strJosu = "2" Or strJosu = "3" Or strJosu = "5" Or strJosu = "6" Or strJosu = "7" Then
pfConvertSameName = Mid(item, 3, 6) & "d"
ElseIf strJosu = "9" Then '競走馬(特別登録馬)
pfConvertSameName = Mid(item, 3, 6) & "l"
ElseIf strJosu = "0" Then '競走馬(新規馬名登録馬)
pfConvertSameName = Mid(item, 3, 6) & "m"
Else '競走馬(年単位他)
pfConvertSameName = "aa" & Mid(item, 3, 6)
End If
Case "t" '特別登録馬
If strJosu = "t" Then
pfConvertSameName = Mid(item, 3, 6) & "k"
End If
Case "a" '競走馬(中央初出走馬)
If strJosu = "1" Or strJosu = "2" Or strJosu = "3" Or strJosu = "5" Or strJosu = "6" Or strJosu = "7" Then
pfConvertSameName = Mid(item, 3, 6) & "e"
End If
Case "d" '出馬表・競走馬
If strJosu = "d" Then
pfConvertSameName = "bb" & Mid(item, 3, 6)
Else
pfConvertSameName = Mid(item, 3, 6) & "g"
End If
Case "v" '票数
If strJosu = "v" Then
pfConvertSameName = "cc" & Mid(item, 3, 6)
Else
pfConvertSameName = Mid(item, 3, 6) & "h"
End If
Case "o" 'オッズ
If strJosu = "o" Then
pfConvertSameName = "dd" & Mid(item, 3, 6)
Else
pfConvertSameName = Mid(item, 3, 6) & "i"
End If
Case "s" '成績
If strJosu = "s" Then
pfConvertSameName = "ee" & Mid(item, 3, 6)
ElseIf strJosu = "5" Or strJosu = "6" Then '地方
pfConvertSameName = Mid(item, 3, 6) & "f"
Else
pfConvertSameName = Mid(item, 3, 6) & "j"
End If
Case "m" '抹消ファイル
pfConvertSameName = Mid(item, 3, 6) & "a"
Case Else
pfConvertSameName = item
End Select
Exit_pfConvertSameName:
Exit Function
Err_pfConvertSameName:
MsgBox Err.Number & vbCrLf & Err.Description & vbCrLf & "Place: pfConvertSameName"
Resume Exit_pfConvertSameName
End Function
--------------------------------------------------------------------------------------------------------
以下のようにファイルが並ぶので，今年の日別ファイルの再組込み等が楽になります。